FastReport VCL是用于 Delphi、C++ Builder、RAD Studio 和 Lazarus 的報告和文檔創建 VCL 庫。它提供了可視化模板設計器，可以訪問 30 多種格式，并可以部署到云、網站、電子郵件和打印中。

立即點擊下載FastReport VCL v6.9最新版

當你在設計器中選擇一個組件時，它的屬性會顯示在對象檢查器中。你可以為任何屬性創建你自己的編輯器。"字體 "屬性的標準編輯器可以作為例子：如果這個屬性被選中，在行的右側出現...按鈕；通過點擊這個按鈕調用標準的 "字體屬性 "對話框。還有一個例子是 "顏色 "屬性編輯器。它在下拉列表中顯示標準顏色和顏色規格名稱。

所有屬性編輯器的基類在 "frxDsgnIntf "單元中描述。

  TfrxPropertyEditor = class(TObject)
  protected
    procedure GetStrProc(const s: String);
    function GetFloatValue: Extended;
    function GetOrdValue: Integer;
    function GetStrValue: String;
    function GetVarValue: Variant;
    procedure SetFloatValue(Value: Extended);
    procedure SetOrdValue(Value: Integer);
    procedure SetStrValue(const Value: String);
    procedure SetVarValue(Value: Variant);
  public
    constructor Create(Designer: TfrxCustomDesigner); virtual;
    destructor Destroy; override;
    function Edit: Boolean; virtual;
    function GetAttributes: TfrxPropertyAttributes; virtual;
    function GetExtraLBSize: Integer; virtual;
    function GetValue: String; virtual;
    procedure GetValues; virtual;
    procedure SetValue(const Value: String); virtual;
    procedure OnDrawLBItem(Control: TWinControl; Index: Integer; ARect: TRect; State: TOwnerDrawState); virtual;
    procedure OnDrawItem(Canvas: TCanvas; ARect: TRect); virtual;
    property Component: TPersistent readonly;
    property frComponent: TfrxComponent readonly;
    property Designer: TfrxCustomDesigner readonly;
    property ItemHeight: Integer;
    property PropInfo: PPropInfo readonly;
    property Value: String;
    property Values: TStrings readonly;
  end;

  TfrxIntegerProperty = class(TfrxPropertyEditor)
  TfrxFloatProperty = class(TfrxPropertyEditor)
  TfrxCharProperty = class(TfrxPropertyEditor)
  TfrxStringProperty = class(TfrxPropertyEditor)
  TfrxEnumProperty = class(TfrxPropertyEditor)
  TfrxClassProperty = class(TfrxPropertyEditor)
  TfrxComponentProperty = class(TfrxPropertyEditor)

• Component - 鏈接到父級組件（不是屬性本身！），給定的屬性屬于該組件。
• frComponent - 相同的，但被投到TfrxComponent類型（為了在某些情況下方便）。
• Designer - 通往報告設計器的鏈接。
• ItemHeight - 項目高度，屬性在其中顯示。它在OnDrawXXX中很有用。
• PropInfo - 鏈接到PPropInfo結構，它包含了關于已編輯屬性的信息。
• Value - 顯示為字符串的屬性值。
• Values - 值的列表。如果定義了 "paValueList "屬性（見下文），這個屬性將被填入GetValue方法中。

    function GetFloatValue: Extended;
    function GetOrdValue: Integer;
    function GetStrValue: String;
    function GetVarValue: Variant;
    procedure SetFloatValue(Value: Extended);
    procedure SetOrdValue(Value: Integer);
    procedure SetStrValue(const Value: String);
    procedure SetVarValue(Value: Variant);

MyFont := TFont(GetOrdValue)

TfrxPropertyAttribute = (paValueList, paSortList, paDialog, paMultiSelect, paSubProperties, paReadOnly, paOwnerDraw);
TfrxPropertyAttributes = set of TfrxPropertyAttribute;

• paValueList - 屬性代表下拉式的數值列表。這個功能以 "顏色 "屬性為例）。如果這個屬性存在，GetValues方法應該被重寫。
• paSortList - 對列表元素進行排序。它與paValueList一起使用。
• paDialog - 屬性有編輯器。如果這個屬性存在，...按鈕將顯示在編輯行的右邊部分。通過點擊它，編輯方法被調用。
• paMultiSelect - 允許在同時選擇的一些對象中編輯給定的屬性。一些屬性（如 "名稱 "等）沒有這個屬性。
• paSubProperties - 屬性是TPersistent類型的對象，并且有它自己的屬性，這些屬性也應該被顯示。這個功能在 "字體 "屬性中得到了體現）。
• paReadOnly - 不可能在編輯行中修改值。一些屬性，作為 "類 "或 "設置 "類型，擁有這個屬性。
• paOwnerDraw - 屬性值的繪制是通過OnDrawItem方法進行的。如果 "paValueList "屬性被定義，那么下拉列表的繪制是通過OnDrawLBItem方法進行的。

GetValue方法應該以字符串形式返回屬性值（它將顯示在對象檢查器中）。如果你繼承了TfrxPropertyEditor基本類，有必要覆蓋這個方法。

SetValue方法是用來設置屬性值轉移為字符串。如果你繼承自TfrxPropertyEditor基本類，就有必要覆蓋這個方法。

如果你定義了 "paValueList "屬性，GetValues方法應該被覆蓋。這個方法應該用值來填充數值屬性。
下面三個方法允許執行手動屬性值繪制（顏色屬性編輯器以同樣的方式工作）。如果你定義了 "paOwnerDraw "屬性，這些方法將被調用。
OnDrawItem方法在對象檢查器中繪制屬性值時被調用（當屬性未被選中時；否則它的值將簡單地顯示在編輯行中）。例如，顏色屬性編輯器會在屬性值的左邊繪制矩形，并根據顏色填充。
如果你定義了 "paValueList "屬性，GetExtraLBSize方法將被調用。該方法返回像素數，"下拉列表 "的寬度應該被調整，以便為顯示的圖片找到空間。默認情況下，該方法返回對應于屬性包絡的單元格高度的值。如果你需要推導出寬度大于高度的圖片，應該重寫給定的方法。
OnDrawLBItem方法在下拉列表中繪制字符串時被調用，如果你定義了paValueList屬性。事實上，這個方法是TListBox.OnDrawItem事件處理程序，并且有相同的參數集。
屬性編輯器的注冊是通過frxDsgnIntf文件中描述的程序進行的。

procedure frxPropertyEditors.Register(PropertyType: PTypeInfo; ComponentClass: TClass; const PropertyName: String; EditorClass: TfrxPropertyEditorClass);

• PropertyType - 關于屬性類型的信息，通過 "TypeInfo "系統函數傳輸，例如TypeInfo(String)。
• ComponentClass - 組件名稱，有你要編輯的屬性（可以是nil）。
• PropertyName - 你要編輯的屬性的名稱（可以是空白字符串）。
• EditorClass - 屬性編輯器名稱

{ TFont property editor displays editor button(...) }
{ inherit from ClassProperty }

type
 TfrxFontProperty = class(TfrxClassProperty)
  public
    function Edit: Boolean; override;
    function GetAttributes: TfrxPropertyAttributes; override;
  end;

function TfrxFontProperty.GetAttributes: TfrxPropertyAttributes;
begin
  {  property has nested properties and  editor. It cannot be edited manually }
  Result := [paMultiSelect, paDialog, paSubProperties, paReadOnly];
end;

function TfrxFontProperty.Edit: Boolean;
var
  FontDialog: TFontDialog;
begin
  { create standard dialogue }
  FontDialog := TFontDialog.Create(Application);
  try
    { take  property value }
    FontDialog.Font := TFont(GetOrdValue);
    FontDialog.Options := FontDialog.Options + [fdForceFontExist];
    { display dialogue }
    Result := FontDialog.Execute;
    { bind new value }
    if Result then
      SetOrdValue(Integer(FontDialog.Font));
  finally
    FontDialog.Free;
  end;
end;

{ registration }

frxPropertyEditors.Register(TypeInfo(TFont), nil, '', TfrxFontProperty);

{ TFont.Name property editor displays  drop-down list of available fonts }
{ inherit from StringProperty, as property is of string type }

type
  TfrxFontNameProperty = class(TfrxStringProperty)
  public
    function GetAttributes: TfrxPropertyAttributes; override;
    procedure GetValues; override;
  end;

function TfrxFontNameProperty.GetAttributes: TfrxPropertyAttributes;
begin
  Result := [paMultiSelect, paValueList];
end;

procedure TfrxFontNameProperty.GetValues;
begin
  Values.Assign(Screen.Fonts);
end;

{ registration }

frxPropertyEditors.Register(TypeInfo(String), TFont, 'Name', TfrxFontNameProperty);

{ TPen.Style property editor displays picture, which is pattern of selected style }

type
  TfrxPenStyleProperty = class(TfrxEnumProperty)
  public
    function GetAttributes: TfrxPropertyAttributes; override;
    function GetExtraLBSize: Integer; override;
    procedure OnDrawLBItem(Control: TWinControl; Index: Integer;
      ARect: TRect; State: TOwnerDrawState); override;
    procedure OnDrawItem(Canvas: TCanvas; ARect: TRect); override;
  end;

function TfrxPenStyleProperty.GetAttributes: TfrxPropertyAttributes;
begin
  Result := [paMultiSelect, paValueList, paOwnerDraw];
end;

{ method draws thick horizontal line with selected style }
procedure HLine(Canvas: TCanvas; X, Y, DX: Integer);
var
  i: Integer;
begin
  with Canvas do
  begin
    Pen.Color := clBlack;
    for i := 0 to 1 do
    begin
      MoveTo(X, Y - 1 + i);
      LineTo(X + DX, Y - 1 + i);
    end;
  end;
end;

{ drawing drop-down list }
procedure TfrxPenStyleProperty.OnDrawLBItem(Control: TWinControl; Index: Integer; ARect: TRect; State: TOwnerDrawState);
begin
  with TListBox(Control), TListBox(Control).Canvas do
  begin
    FillRect(ARect);
    TextOut(ARect.Left + 40, ARect.Top + 1, TListBox(Control).Items[Index]);
    Pen.Color := clGray;
    Brush.Color := clWhite;
    Rectangle(ARect.Left + 2, ARect.Top + 2, ARect.Left + 36, ARect.Bottom - 2);
    Pen.Style := TPenStyle(Index);
    HLine(TListBox(Control).Canvas, ARect.Left + 3, ARect.Top + (ARect.Bottom - ARect.Top) div 2, 32);
    Pen.Style := psSolid;
  end;
end;

{ drawing property value }
procedure TfrxPenStyleProperty.OnDrawItem(Canvas: TCanvas; ARect: TRect);
begin
  with Canvas do
  begin
    TextOut(ARect.Left + 38, ARect.Top, Value);
    Pen.Color := clGray;
    Brush.Color := clWhite;
    Rectangle(ARect.Left, ARect.Top + 1, ARect.Left + 34, ARect.Bottom - 4);
    Pen.Color := clBlack;
    Pen.Style := TPenStyle(GetOrdValue);
    HLine(Canvas, ARect.Left + 1, ARect.Top + (ARect.Bottom - ARect.Top) div 2 - 1, 32);
    Pen.Style := psSolid;
  end;
end;

{ return  picture width }
function TfrxPenStyleProperty.GetExtraLBSize: Integer;
begin
  Result := 36;
end;

{ registration }
frxPropertyEditors.Register(TypeInfo(TPenStyle), TPen, 'Style', TfrxPenStyleProperty);

如果您對 FastReport 感興趣，歡迎加入 FastReport QQ 交流群：702295239

還想要更多嗎？您可以點擊閱讀【FastReport報表2021最新資源盤點】，查找需要的教程資源。上是FastReport .NET慧正在網火熱銷售中!>>查看價格詳情